gb-tarot/ScreenCardBrowse.inc

; screen variables already ddefined in screencardread
;DEF vPreviousCardIndex EQU VARIABLES_START
;def vBlocked equ vPreviousCardIndex + 1 

ScreenCardBrowse:
  dw CardBrowseSetup
  dw CardBrowseUpdate
  dw CardBrowseDraw
  dw CardBrowseTeardown

CardBrowseSetup:
  ld a, 1 
  ldh [vBlocked], a 
  
  ld a, LOW(RunDMA) ; zero out the OAM
  ld [vAsyncNext], a 
  ld a, HIGH(RunDMA)
  ld [vAsyncNext+1], a 
  ld a, LOW(.loadUIMap)
  ld [vAsyncAfter], a 
  ld a, HIGH(.loadUIMap)
  ld [vAsyncAfter+1], a 

  ld a, HIGH(ZEROES)
  ld de, $ffc0 ; arguments to the first async call.
  
  call DoInAsyncVBlank
  ret
  
.loadUIMap

  ld hl, CardBrowse.UITilemap ; origin
  ld de, $9800 ; destination
  ld b, 18 ; height
  ld c, 20 ; width
  
  ld a, LOW(CopyTilesToMapThreadsafe)
  ld [vAsyncNext], a 
  ld a, HIGH(CopyTilesToMapThreadsafe)
  ld [vAsyncNext+1], a 
  
  ld a, LOW(LoadCardDataAsync)
  ld [vAsyncAfter], a 
  ld a, HIGH(LoadCardDataAsync)
  ld [vAsyncAfter+1], a 
  ret

CardBrowseUpdate:
  ld hl, vTime
  ldh a, [rDELTAT]
  ld b, a 
  ldh a, [vTime]
  add a, b
  ldh [vTime], a 
  ldh a, [vTime+1]
  adc a, 0 
  ldh [vTime+1], a ; increment time. when the 16bit time register is greater 
  ; than 4096 ($10_00) then one second has passed. so that's satisfied when
  ; vTime+1 is equal to or greater than $10
  
  ldh a, [vTime+1]
  cp a, $01
  jp c, .doneTimer ; if the timer is less than $0100, skip to end
  
  ;otherwise reset the timer
  ld a, 0 
  ldh [vTime], a 
  ldh [vTime+1], a 
  
  ld hl, SquaresTiles
  ldh a, [vFrameCountSquares]
  inc a
  call ArrayClampLooping
  ldh [vFrameCountSquares], a 

.doneTimer
  ld hl, rMYBTNP
  bit 4, [hl]
  jp z, .doneWithB
  ld hl, ScreenMainMenu
  call ChangeScene
  ret
.doneWithB
  
  ldh a, [vSelectedCardIndex]
  ld hl, rMYBTNP
  bit 3, [hl]
  jp z, :+ ; skip the following code if down is not pressed
  inc a 
:
  bit 2, [hl]
  jp z, :+ ; skip the following code if up is not pressed
  dec a 
:
  ldh [vSelectedCardIndex], a 
  ld hl, Cards 
  call ArrayClampLooping
  ldh [vSelectedCardIndex], a 
  
  ldh a, [vSelectedCardIndex]
  ld hl, vPreviousCardIndex
  cp a, [hl]
  ret z ; if the selected card diddn't change, nothing to do
  
  ldh a, [vBlocked]
  cp a, 0 
  ret nz
  
  ld a, LOW(LoadCardDataAsync)
  ld [vAsyncAfter], a 
  ld a, HIGH(LoadCardDataAsync)
  ld [vAsyncAfter+1], a 
  call DoInAsyncVBlank
  
  
  ret

CardBrowseDraw:
  ; the card data is loaded asynchronously, initiated in CardReadUpdate
  
  ld hl, SquaresTiles
  inc hl 
  ld b, 0
  ldh a, [vFrameCountSquares]
  ld c, a 
  add hl, bc 
  add hl, bc
  ld c, [hl]
  inc hl
  ld b, [hl]
  ld h, b
  ld l, c
  ld de, $8000+$100*16 + 1*16
  ld bc, (SquaresTileset8 - SquaresTileset7) / 8
  call CopyRangeUnsafeBy8s
  
  call DrawDeckMinimap
  ret

DrawDeckMinimap:
  ld hl, Cards 
  ld c, [hl] ; count of cards
  srl c 
  set 0, c
  
  ld hl, vSelectedCardIndex
  ld d, [hl] ; selected card!
  ld b, $ff ; start at -1 lol
  ld hl, $9800 + 32 + 11
  
.loop
  inc b
  ld a, b
  cp a, 5
  jp nz, .noNewLine
  ld [hl], $13
  ld hl, $9800 + 32*2 + 11
.noNewLine
  ld a, b
  cp a, c 
  jp nc, .doneDrawing
  ld a, d 
  srl a 
  cp a, b
  jp z, .drawSelectedCard
.drawUnselectedCards
  ld [hl], $12
  inc hl
  jp .loop
.drawSelectedCard
  bit 0, d 
  jp nz, .drawSelectedSecond
  ld [hl], $14
  inc hl
  jp .loop
.drawSelectedSecond
  ld [hl], $15
  inc hl
  jp .loop
.doneDrawing
  ld [hl], $13
  ret
  
  
CardBrowseTeardown:
  ret



CardBrowse.UITilemap:
	db $0e, $0a, $0a, $0a, $0a, $0a, $0a, $0a, $0a, $0f, $09, $02, $02, $02, $02, $02, $02, $02, $08, $01
	db $0b, $00, $00, $00, $00, $00, $00, $00, $00, $0c, $03, $00, $00, $00, $00, $00, $00, $00, $04, $01
	db $0b, $00, $00, $00, $00, $00, $00, $00, $00, $0c, $03, $00, $00, $00, $00, $00, $00, $00, $04, $01
	db $0b, $00, $00, $00, $00, $00, $00, $00, $00, $0c, $06, $05, $05, $05, $05, $05, $05, $05, $07, $01
	db $0b, $00, $00, $00, $00, $00, $00, $00, $00, $0c, $01, $01, $01, $01, $01, $01, $01, $01, $01, $01
	db $0b, $00, $00, $00, $00, $00, $00, $00, $00, $0c, $01, $01, $01, $01, $01, $01, $01, $01, $01, $01
	db $0b, $00, $00, $00, $00, $00, $00, $00, $00, $0c, $01, $01, $01, $01, $01, $01, $01, $01, $01, $01
	db $0b, $00, $00, $00, $00, $00, $00, $00, $00, $0c, $01, $01, $01, $01, $01, $01, $01, $01, $01, $01
	db $0b, $00, $00, $00, $00, $00, $00, $00, $00, $0c, $01, $01, $01, $01, $01, $01, $01, $01, $01, $01
	db $0b, $00, $00, $00, $00, $00, $00, $00, $00, $0c, $01, $01, $01, $01, $01, $01, $01, $01, $01, $01
	db $0b, $00, $00, $00, $00, $00, $00, $00, $00, $0c, $02, $02, $02, $02, $02, $02, $02, $02, $02, $02
	db $0b, $00, $00, $00, $00, $00, $00, $00, $00, $0c, $00, $00, $00, $00, $00, $00, $00, $00, $00, $00
	db $0b, $00, $00, $00, $00, $00, $00, $00, $00, $0c, $00, $00, $00, $00, $00, $00, $00, $00, $00, $00
	db $0b, $00, $00, $00, $00, $00, $00, $00, $00, $0c, $00, $00, $00, $00, $00, $00, $00, $00, $00, $00
	db $0b, $00, $00, $00, $00, $00, $00, $00, $00, $0c, $00, $00, $00, $00, $00, $00, $00, $00, $00, $00
	db $0b, $00, $00, $00, $00, $00, $00, $00, $00, $0c, $00, $00, $00, $00, $00, $00, $00, $00, $00, $00
	db $0b, $00, $00, $00, $00, $00, $00, $00, $00, $0c, $00, $00, $00, $00, $00, $00, $00, $00, $00, $00
	db $11, $0d, $0d, $0d, $0d, $0d, $0d, $0d, $0d, $10, $00, $00, $00, $00, $00, $00, $00, $00, $00, $00
CardBrowse.UITilemapEnd: